Quantum tunneling through a square barrier

Remove["Global`*"]

u1[x_]=a Exp[I k x]+b Exp[-I k x];
u2[x_]=c Exp[α x]+d Exp[-α x];
u3[x_]=e Exp[I k x];

sol=Solve[
{u1[0]==u2[0],u1'[0]==u2'[0],
u2[s]==u3[s],u2'[s]==u3'[s]},
{b,c,d,e}];

trans=Part[
ComplexExpand[
Simplify[Abs[e/a]^2/.sol,
k>0 && α>0 && s>0]],1];

transplot=Simplify[
trans/.{s->z/k,α->k Sqrt[(1/ϵ-1)]}];

LogLogPlot[
{transplot/.z->0.1,
transplot/.z->0.05,
transplot/.z->0.01},{ϵ,0.001,1},
PlotLegends->{"s=0.1/k","s=0.05/k","s=0.01/k"},
AxesLabel->{"E/V0","Probability of Transmission"}]