Some equations from Maoz Chapter 2

Remove["Global`*"]

Typing in (2.1)

uν=(8 Pi ν^2/c^3)h ν/(Exp[h ν/(k T)]-1)

Integrate to get (2.9)

u=Simplify[
Integrate[uν,{ν,0,∞}],
{h>0,k>0,T>0}]

Extract and evaluate the constant

a=u/T^4

kVal=QuantityMagnitude[
UnitConvert[Quantity["BoltzmanConstant"],"erg/K"]];
cVal=QuantityMagnitude[
UnitConvert[Quantity["SpeedOfLight"],"cm/s"]];
hVal=QuantityMagnitude[
UnitConvert[Quantity["PlanckConstant"],"erg s"]];

a/.{k->kVal,c->cVal,h->hVal}

This agrees with what’s at the top of page 13

Now find the blackbody radiation spectrum as a function of wavelength

Bν=(c/(4 Pi))uν;
Bλ=(c/λ^2)Bν/.ν->c/λ

This is Equation (2.12). Now put in the numbers and make a plot for some temperature

BλPlot=Bλ/.{k->kVal,c->cVal,h->hVal,T->5000}/.λ->10^(-7)λnm;
Plot[BλPlot,{λnm,0,2000}]

Finally, derive Wien’s Law, Equation (2.15)

BλSolve=Bλ/.λ->h c/(k T x);
NSolve[D[BλSolve,x]==0,x];
λMax=Part[h c/(k T x)/.%,1]/.{k->kVal,c->cVal,h->hVal}