Rae & Napolitano 6e Figure 5.2 and Table 5.1

Remove["Global`*"]

eqPos=ka Tan[ka]==Sqrt[k0a^2-ka^2];
eqNeg=-ka Cot[ka]==Sqrt[k0a^2-ka^2];

lhsPos=eqPos[[1]];
lhsNeg=eqNeg[[1]];
circle=eqPos[[2]];

k0a=5;

Show[
Plot[circle,{ka,0,2Pi},
PlotStyle->Black,
PlotRange->{{0,6},{0,6}},
AspectRatio->1],
Plot[lhsPos,{ka,0,2Pi},
PlotStyle->Red],
Plot[lhsNeg,{ka,0,2Pi},
PlotStyle->Blue]]

ka1=ka/.FindRoot[eqPos,{ka,1}];
ka2=ka/.FindRoot[eqNeg,{ka,2.5}];
ka3=ka/.FindRoot[eqPos,{ka,4}];
ka4=ka/.FindRoot[eqNeg,{ka,5}];

kas=Re[{ka1,ka2,ka3,ka4}];
κas=Sqrt[k0a^2-kas^2];

EV0=ϵ/.Solve[κa==k0a Sqrt[1-ϵ],ϵ][[1]];
EV0s=EV0/.κa->κas;

EEinfs=(4/Pi^2)kas^2/{1,2,3,4}^2;

Grid[Transpose[{kas,κas,EV0s,EEinfs}]]